Added iOS text classifier

mediapipe/tasks/ios/text/text_classifier/BUILD

@@ -35,3 +35,24 @@ objc_library(
     ],
 )
 
+objc_library(
+    name = "MPPTextClassifier",
+    srcs = ["sources/MPPTextClassifier.mm"],
+    hdrs = ["sources/MPPTextClassifier.h"],
+    copts = [
+        "-ObjC++",
+        "-std=c++17",
+    ],
+    deps = [
+        "//mediapipe/tasks/cc/text/text_classifier:text_classifier_graph",
+        "//mediapipe/tasks/ios/core:MPPTaskOptions",
+        "//mediapipe/tasks/ios/core:MPPTaskInfo",
+        "//mediapipe/tasks/ios/text/core:MPPTextTaskRunner",
+        "//mediapipe/tasks/ios/core:MPPTextPacketCreator",
+        "//mediapipe/tasks/ios/text/text_classifier/utils:MPPTextClassifierOptionsHelpers",
+        "//mediapipe/tasks/ios/text/text_classifier/utils:MPPTextClassifierResultHelpers",
+        "//mediapipe/tasks/ios/common/utils:MPPCommonUtils",
+        "//mediapipe/tasks/ios/common/utils:NSStringHelpers",
+        ":MPPTextClassifierOptions",
+    ],
+)

mediapipe/tasks/ios/text/text_classifier/sources/MPPTextClassifier.h

@@ -0,0 +1,103 @@
+// Copyright 2023 The MediaPipe Authors.
+//
+// Licensed under the Apache License, Version 2.0 (the "License");
+// you may not use this file except in compliance with the License.
+// You may obtain a copy of the License at
+//
+//      http://www.apache.org/licenses/LICENSE-2.0
+//
+// Unless required by applicable law or agreed to in writing, software
+// distributed under the License is distributed on an "AS IS" BASIS,
+// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+// See the License for the specific language governing permissions and
+// limitations under the License.
+
+#import <Foundation/Foundation.h>
+
+#import "mediapipe/tasks/ios/core/sources/MPPTaskOptions.h"
+#import "mediapipe/tasks/ios/text/text_classifier/sources/MPPTextClassifierOptions.h"
+#import "mediapipe/tasks/ios/text/text_classifier/sources/MPPTextClassifierResult.h"
+
+NS_ASSUME_NONNULL_BEGIN
+
+/**
+ * @brief Performs classification on text.
+ * 
+ * This API expects a TFLite model with (optional) [TFLite Model
+ * Metadata](https://www.tensorflow.org/lite/convert/metadata")that contains the mandatory
+ * (described below) input tensors, output tensor, and the optional (but recommended) label 
+ * items as AssociatedFiles with type TENSOR_AXIS_LABELS per output classification tensor.
+ *
+ * Metadata is required for models with int32 input tensors because it contains the input 
+ * process unit for the model's Tokenizer. No metadata is required for models with string 
+ * input tensors.
+ *
+ * Input tensors
+ *  - Three input tensors `kTfLiteInt32` of shape `[batch_size xbert_max_seq_len]`
+ *    representing the input ids, mask ids, and segment ids. This input signature requires 
+ *    a Bert Tokenizer process unit in the model metadata.
+ *  - Or one input tensor `kTfLiteInt32` of shape `[batch_size xmax_seq_len]` representing
+ *    the input ids. This input signature requires a Regex Tokenizer process unit in the
+ *    model metadata.
+ *  - Or one input tensor (`kTfLiteString`) that is shapeless or has shape `[1]` containing
+ *    the input string.
+ *
+ * At least one output tensor (`kTfLiteFloat32/kBool`) with:
+ *  - `N` classes and shape `[1 x N]`
+ *  - optional (but recommended) label map(s) as AssociatedFiles with type 
+ *    TENSOR_AXIS_LABELS,
+ *    containing one label per line. The first such AssociatedFile (if any) is used to fill 
+ *    the `categoryName` field of the results. The `displayName` field is filled from the 
+ *    AssociatedFile (if any) whose locale matches the `displayNamesLocale` field of the 
+ *    `MPPTextClassifierOptions` used at creation time ("en" by default, i.e. English). If 
+ *    none of these are available, only the `index` field of the results will be filled.
+ */
+NS_SWIFT_NAME(TextClassifier)
+@interface MPPTextClassifier : NSObject
+
+/**
+ * Creates a new instance of `MPPTextClassifier` from an absolute path to a TensorFlow Lite
+ * model file stored locally on the device and the default `MPPTextClassifierOptions`.
+ *
+ * @param modelPath An absolute path to a TensorFlow Lite model file stored locally on the
+ * device.
+ * @param error An optional error parameter populated when there is an error in initializing
+ * the text classifier.
+ *
+ * @return A new instance of `MPPTextClassifier` with the given model path. `nil` if there is an
+ * error in initializing the text classifier.
+ */
+- (instancetype)initWithModelPath:(NSString *)modelPath error:(NSError **)error;
+
+/**
+ * Creates a new instance of `MPPTextClassifier` from the given `MPPTextClassifierOptions`.
+ *
+ * @param options The options of type `MPPTextClassifierOptions` to use for configuring the
+ * `MPPTextClassifier`.
+ * @param error An optional error parameter populated when there is an error in initializing
+ * the text classifier.
+ *
+ * @return A new instance of `MPPTextClassifier` with the given options. `nil` if there is an
+ * error in initializing the text classifier.
+ */
+- (instancetype)initWithOptions:(MPPTextClassifierOptions *)options
+                          error:(NSError **)error NS_DESIGNATED_INITIALIZER;
+
+/**
+ * Performs classification on the input text.
+ *
+ * @param text The `NSString` on which classification is to be performed.
+ * @param error An optional error parameter populated when there is an error in performing
+ * classification on the input text.
+ *
+ * @return  A `MPPTextClassifierResult` object that contains a list of text classifications.
+ */
+- (nullable MPPTextClassifierResult *)classifyText:(NSString *)text error:(NSError **)error;
+
+- (instancetype)init NS_UNAVAILABLE;
+
++ (instancetype)new NS_UNAVAILABLE;
+
+@end
+
+NS_ASSUME_NONNULL_END

mediapipe/tasks/ios/text/text_classifier/sources/MPPTextClassifier.mm

@@ -0,0 +1,98 @@
+// Copyright 2023 The MediaPipe Authors.
+//
+// Licensed under the Apache License, Version 2.0 (the "License");
+// you may not use this file except in compliance with the License.
+// You may obtain a copy of the License at
+//
+//      http://www.apache.org/licenses/LICENSE-2.0
+//
+// Unless required by applicable law or agreed to in writing, software
+// distributed under the License is distributed on an "AS IS" BASIS,
+// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+// See the License for the specific language governing permissions and
+// limitations under the License.
+
+#import "mediapipe/tasks/ios/text/text_classifier/sources/MPPTextClassifier.h"
+
+#import "mediapipe/tasks/ios/common/utils/sources/MPPCommonUtils.h"
+#import "mediapipe/tasks/ios/common/utils/sources/NSString+Helpers.h"
+#import "mediapipe/tasks/ios/core/sources/MPPTaskInfo.h"
+#import "mediapipe/tasks/ios/core/sources/MPPTextPacketCreator.h"
+#import "mediapipe/tasks/ios/text/core/sources/MPPTextTaskRunner.h"
+#import "mediapipe/tasks/ios/text/text_classifier/utils/sources/MPPTextClassifierOptions+Helpers.h"
+#import "mediapipe/tasks/ios/text/text_classifier/utils/sources/MPPTextClassifierResult+Helpers.h"
+
+#include "absl/status/statusor.h"
+#include "mediapipe/tasks/cc/components/containers/proto/classifications.pb.h"
+
+namespace {
+using ::mediapipe::Packet;
+using ::mediapipe::tasks::components::containers::proto::ClassificationResult;
+using ::mediapipe::tasks::core::PacketMap;
+}  // namespace
+
+static NSString *const kClassificationsStreamName = @"classifications_out";
+static NSString *const kClassificationsTag = @"CLASSIFICATIONS";
+static NSString *const kTextInStreamName = @"text_in";
+static NSString *const kTextTag = @"TEXT";
+static NSString *const kTaskGraphName = @"mediapipe.tasks.text.text_classifier.TextClassifierGraph";
+
+@interface MPPTextClassifier () {
+  /** iOS Text Task Runner */
+  MPPTextTaskRunner *_textTaskRunner;
+}
+@end
+
+@implementation MPPTextClassifier
+
+- (instancetype)initWithOptions:(MPPTextClassifierOptions *)options error:(NSError **)error {
+  MPPTaskInfo *taskInfo = [[MPPTaskInfo alloc]
+      initWithTaskGraphName:kTaskGraphName
+               inputStreams:@[ [NSString stringWithFormat:@"%@:%@", kTextTag, kTextInStreamName] ]
+              outputStreams:@[ [NSString stringWithFormat:@"%@:%@", kClassificationsTag,
+                                                          kClassificationsStreamName] ]
+                taskOptions:options
+         enableFlowLimiting:NO
+                      error:error];
+
+  if (!taskInfo) {
+    return nil;
+  }
+
+  _textTaskRunner =
+      [[MPPTextTaskRunner alloc] initWithCalculatorGraphConfig:[taskInfo generateGraphConfig]
+                                                         error:error];
+  
+  if (!_textTaskRunner) {
+    return nil;
+  }                                                      
+  
+  self = [super init];
+
+  return self;
+}
+
+- (instancetype)initWithModelPath:(NSString *)modelPath error:(NSError **)error {
+  MPPTextClassifierOptions *options = [[MPPTextClassifierOptions alloc] init];
+
+  options.baseOptions.modelAssetPath = modelPath;
+
+  return [self initWithOptions:options error:error];
+}
+
+- (nullable MPPTextClassifierResult *)classifyText:(NSString *)text error:(NSError **)error {
+  Packet packet = [MPPTextPacketCreator createWithText:text];
+
+  std::map<std::string, Packet> packetMap = {{kTextInStreamName.cppString, packet}};
+  absl::StatusOr<PacketMap> statusOrOutputPacketMap = [_textTaskRunner process:packetMap];
+
+  if (![MPPCommonUtils checkCppError:statusOrOutputPacketMap.status() toError:error]) {
+    return nil;
+  }
+
+  return [MPPTextClassifierResult
+      textClassifierResultWithClassificationsPacket:statusOrOutputPacketMap.value()
+                                                        [kClassificationsStreamName.cppString]];
+}
+
+@end